Excel-Formeln aus meinem Facebook-Archiv – und wie ich sie heute schreiben würde

16.10.2026

Im Dezember 2013 schrieb ich auf Facebook:

Hab i eigentlich scho mal erwähnt, dass i Excel ziemlich geil find? ;)

Beim Durchsehen meines Facebook-Archivs sind mehrere solche Beiträge aufgetaucht. Jeder mit einer Formel, auf die ich damals stolz war. Hier sind sie, jeweils mit einer Fassung, wie ich sie heute schreiben würde.

1. Eine Spalte prüfen und umbauen (2013)

So simpel kann man ein paar Wochen manuellen Zeitaufwand einsparen... ;)

=WENN(LINKS(F7;1)="-";"Prüfen";WENN(ODER(LINKS(F7;1)="+";F7="");(WECHSELN(F7;"/";" "));WECHSELN($L7&" "&TEIL(F7;2;LÄNGE(F7));"/";" ")))

Beginnt der Eintrag mit einem Minus, soll ihn jemand prüfen. Beginnt er mit Plus oder ist er leer, werden nur Schrägstriche zu Leerzeichen. Sonst kommt ein Wert aus Spalte L davor.

Heute würde ich mit LET Zwischenwerte benennen. Dann muss man F7 und LINKS(F7;1) nicht mehrfach lesen:

=LET(t;F7;z;LINKS(t;1);
  WENN(z="-";"Prüfen";
    WECHSELN(WENN(ODER(z="+";t="");t;$L7&" "&TEIL(t;2;LÄNGE(t)));"/";" ")))

2. Umlaute ersetzen (2014)

In your Face ihr elendigen Umlaute!

=WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WECHSELN(WENN(BI!C4="";"";WECHSELN(TEIL(BI!C4;FINDEN(" : ";BI!C4;1)+3;255);" : ";" "));"ß";"ss");"ä";"ae");"ö";"oe");"ü";"ue");"Ü";"Ue");"Ö";"Oe");"Ä";"Ae")

Sieben verschachtelte WECHSELN. Funktioniert, aber wer eine Regel ergänzen will, zählt Klammern.

Heute geht das mit zwei Listen und REDUCE. Die Formel geht die Listen der Reihe nach durch und ersetzt jeweils ein Zeichen:

=LET(text;A1;
  von;{"ß";"ä";"ö";"ü";"Ä";"Ö";"Ü"};
  nach;{"ss";"ae";"oe";"ue";"Ae";"Oe";"Ue"};
  REDUCE(text;SEQUENZ(ZEILEN(von));LAMBDA(a;i;WECHSELN(a;INDEX(von;i);INDEX(nach;i)))))

Eine neue Regel ist jetzt nur ein Eintrag mehr in beiden Listen.

3. Handynummern in der falschen Spalte finden (2016)

In einer Datenquelle standen Handynummern teils in der Spalte für Telefon, teils in der für Fax. Meine Lösung damals:

=WENN((SUMME(ZÄHLENWENN(J2;{"*+43 644*";"*+43 650*";"*+43 660*";"*+43 664*";"*+43 665*";"*+43 670*";"*+43 676*";"*+43 677*";"*+43 678*";"*+43 680*";"*+43 681*";"*+43 683*";"*+43 688*";"*+43 699*"}))*1)=1;J2;WENN((SUMME(ZÄHLENWENN(K2;{"*+43 644*";"*+43 650*";"*+43 660*";"*+43 664*";"*+43 665*";"*+43 670*";"*+43 676*";"*+43 677*";"*+43 678*";"*+43 680*";"*+43 681*";"*+43 683*";"*+43 688*";"*+43 699*"}))*1)=1;K2;""))

Damals bat ich die „Excel-Gurus“ in meiner Freundesliste um eine elegantere Lösung. Heute würde ich die Vorwahlen nur einmal hinschreiben:

=LET(v;{"+43 644";"+43 650";"+43 660";"+43 664";"+43 665";"+43 670";"+43 676";"+43 677";"+43 678";"+43 680";"+43 681";"+43 683";"+43 688";"+43 699"};
  mobil;LAMBDA(n;ODER(ISTZAHL(SUCHEN(v;n))));
  WENN(mobil(J2);J2;WENN(mobil(K2);K2;"")))

Noch besser wäre eine eigene kleine Tabelle mit den Vorwahlen. Dann muss niemand die Formel anfassen, wenn eine neue dazukommt.

4. Verbundene Zellen (2017)

Jeder der mich kennt oder schon einmal mit mir zusammengearbeitet hat kennt meine absolute Abneigung (um nicht zu sagen abgrundtiefen Hass) gegenüber verbundenen Zellen in Excel. 😄

Daran hat sich nichts geändert. Verbundene Zellen stören beim Sortieren, Filtern und Kopieren. Wer nur eine Überschrift über mehrere Spalten zentrieren will, nimmt besser: Zellen formatieren → Ausrichtung → Horizontal: Über Auswahl zentrieren. Sieht gleich aus, die Zellen bleiben getrennt.

5. Ein Weihnachtsgeschenk von Microsoft (2018)

Im Dezember 2018 kündigte Microsoft an, dass SVERWEIS, WVERWEIS und VERGLEICH mit exakter Suche deutlich schneller werden. Mein Kommentar damals:

Mein persönliches Weihnachtsgeschenk von Microsoft Excel!

Heute gibt es dafür XVERWEIS. Er sucht in jede Richtung, braucht keine Spaltennummer und hat einen eigenen Wert für „nicht gefunden“:

=XVERWEIS(A2;Kunden[Nummer];Kunden[Name];"nicht gefunden")

Zugabe: ein Makro aus meinen Facebook-Notizen (2012)

Facebook hatte früher eine Notizen-Funktion. Dort habe ich mir 2012 ein kleines VBA-Makro gemerkt. Es macht aus allen Adressen in einer Tabelle anklickbare Links:

Option Explicit
Public Sub Test()
    Dim rngRange As Range
    For Each rngRange In ActiveSheet.UsedRange ' anpassen
        If Left(rngRange.Value, 7) = "http://" Then
            rngRange.Hyperlinks.Add rngRange, rngRange.Value
        End If
    Next rngRange
End Sub

Damals begannen fast alle Adressen mit http://. Heute sind es meistens https://, das Makro würde sie übersehen. Eine kleine Änderung reicht:

If LCase(Left(rngRange.Value, 4)) = "http" Then

Ohne Makro geht es mit einer Hilfsspalte und =HYPERLINK(A2).

Was bleibt

Die alten Formeln haben funktioniert. Sie waren nur schwer zu lesen. Die neuen Funktionen machen vor allem eines besser: Man sieht, was die Formel tun soll.